Schema

package gen

import (
	"github.com/hofstadter-io/hof/schema"
	"github.com/hofstadter-io/hof/schema/common"
	"github.com/hofstadter-io/hof/schema/create"
)

// Definition for a generator
Generator: {
	schema.Hof
	#hof: gen: root: true

	// Base directory for the output
	Outdir: string | *"./"

	// Name of the generator, will default to kebab(label) where defined
	Name: common.NameLabel

	// Generator wide input value to templates.
	// Merged with any template or file level In values
	//   File.In will extend or replace any top-level fields here
	In: {...}

	// Should In be added to the input of every output file?
	applyInToAllOut: bool | *true

	// doing this in the schema crushes CUE performance
	//if applyInToAllOut == true {
	//  Out: [...{"In": In}]
	//}

	// TODO, Generator wide cue.Value for writing incomplete values
	Val: _

	// File globs to watch and trigger regen when changed
	WatchFull: [...string] // reloads & regens everything
	WatchFast: [...string] // skips CUE reload, regens everything

	// Enable Diff3
	Diff3: bool | *true

	// Formatting Control
	Formatting: {
		// default for all files, unless overridden in a file
		Disabled: bool | *false

		// Should data files also be formatted?
		// (cue,yaml,json,toml,xml)
		FormatData: bool | *true

		// Map of names to formatter config values.
		//   Supports multiple configurations for a formatter,
		//   particularly useful for prettier.
		// Hof has defaults it will use if none are specified

		// map from file extensions to formatters
		Formatters: [Extension=string]: {
			// Name of the formatter, like 'prettier' or 'black'
			Formatter: string
			// formatter specific configuration
			Config: _
		}
	}

	PreFlow?:  _ // run hof flow beforehand
	PostFlow?: _ // run hof flow afterwards

	// The final list of files for hof to generate
	Out: [...File]

	// Template (top-level) TemplateConfig (globs+config)
	"Templates": [...Templates] | *[Templates & {Globs: ["./templates/**/*"], TrimPrefix: "./templates/"}]

	// Partial (nested) TemplateConfig (globs+config)
	"Partials": [...Templates] | *[Templates & {Globs: ["./partials/**/*"], TrimPrefix: "./partials/"}]

	// Statics are copied directly into the output, bypassing the rendering
	"Statics": [...Statics] | *[Statics & {Globs: ["./statics/**/*"], TrimPrefix: "./statics/"}]

	// The following mirror their non-embedded versions
	// however they have the content as a string in CUE
	// For templates and partials, Name is the path to reference
	EmbeddedTemplates: [name=string]: Template
	EmbeddedPartials: [name=string]:  Template
	// For statics, Name is the path to write the content
	EmbeddedStatics: [name=string]: string

	// For subgenerators so a generator can leverage and design for other hofmods
	Generators: [name=string]: Generator & {Name: name}

	// Embed the creator to get creator fields
	create.Creator

	// This should be set to default to the module name
	//   (i.e. 'string | *"github.com/<org>/<repo>"')
	// Users should not have to set this.
	// 
	// Used for indexing into the cue.mod/pkg directory...
	// until embed is supported, at which point this shouldn't be needed at all
	// only needed when you have example usage in the same module the generator is in
	// set to the empty string ("") as a generator writer who is making an example in the same module
	ModuleName:  string
	PackageName: ModuleName
	ModuleName:  PackageName
	// TODO, hof, can we introspect the generator / example packages and figure this out?

	// print debug info during load & gen
	Debug: bool | *false

	// TODO, consider adding 'Override*' for templates, partials, statics

	// Note, open so you can have any extra fields
	...
}

// deprecated
#Generator:    Generator
#HofGenerator: Generator

package gen

// A file which should be generated by hof
File: {

	// The local input data, any struct
	// The Generator.In will be merged here
	//   but will not replace any values set locally
	In?: {...} // for templates

	// input value for data files, always remains a CUE value
	Val?: _ // for datafiles

	// The full path under the output location
	// empty implies don't generate, even though it may end up in the out list
	Filepath?: string

	//
	// One and only one of these next three may be set
	//

	// The template contents
	TemplateContent?: string

	// Path into the loaded templates
	TemplatePath?: string

	// Writes a datafile, bypassing template rendering
	// Supports infering DatafileFormat by matching extensions
	// You only have to set this when hof cannot infer from the file extension
	DatafileFormat?: "cue" | "json" | "yaml" | "xml" | "toml"

	// TODO, we would like to make the above a disjunction (multi-field)
	// but it results in a significant slowdown 50-100% for hof self-gen
	// Most likely need to wait for structural sharing to land in cue

	// CUE settings
	// for data files which need a package or namespace at the beginning
	Package:        string | *""
	Raw:            bool | *false
	Final:          bool | *false
	Concrete:       bool | *true
	Definitions:    bool | *true
	Optional:       bool | *true
	Hidden:         bool | *true
	Attributes:     bool | *true
	Docs:           bool | *true
	InlineImports:  bool | *false
	ErrorsAsValues: bool | *false

	// Alternative Template Delimiters
	Delims:          #TemplateDelims
	TemplateDelims?: Delims

	// Formatting Control
	Formatting?: {
		Disabled?: bool
		// Name of the formatter, like 'prettier' or 'black'
		Formatter: string
		// formatter specific configuration
		Config: _
	}

	// note, how In gets combined may be opaque, and non-CUEish
	// we should think about applying it at the schema level

	// local override if the generator is set the opposite way
	applyGenInToOut: bool | *true

	// Note, intentionally closed to prevent user error when creating GenFiles
}

// deprecated
#File:             File
#HofGeneratorFile: File

package gen

#EmptyTemplates: EmptyTemplates
EmptyTemplates: {
	Templates: []
	Partials: []
	Statics: []
	...
}

#SubdirTemplates: SubdirTemplates
SubdirTemplates: {
	#subdir: string | *"."
	Templates: [{
		Globs: ["\(#subdir)/templates/**/*"]
		TrimPrefix: "\(#subdir)/templates/"
	}]
	Partials: [{
		Globs: ["\(#subdir)/partials/**/*"]
		TrimPrefix: "\(#subdir)/partials/"
	}]
	Statics: [{
		Globs: ["\(#subdir)/statics/**/*"]
		TrimPrefix: "\(#subdir)/statics/"
	}]
	...
}

#TemplateSubdirs: TemplateSubdirs
TemplateSubdirs: {
	#subdir: string | *"."
	Templates: [{
		Globs: ["./templates/\(#subdir)/**/*"]
		TrimPrefix: "./templates/\(#subdir)/"
	}]
	Partials: [{
		Globs: ["./partials/\(#subdir)/**/*"]
		TrimPrefix: "./partials/\(#subdir)/"
	}]
	Statics: [{
		Globs: ["./statics/\(#subdir)/**/*"]
		TrimPrefix: "./statics/\(#subdir)/"
	}]
	...
}

// #Statics is used for static files copied over, bypassing the template engine
#Statics: Statics
Statics: {
	Globs: [...string]
	TrimPrefix?: string
	OutPrefix?:  string
}

// #Template is used for embedded or named templates or partials
#Template: Template
Template: {
	Content: string
	Delims?: TemplateDelims
}

// #Templates is used for templates or partials loaded from a filesystem
#Templates: Templates
Templates: {
	Globs: [...string]
	TrimPrefix?: string
	Delims?:     TemplateDelims

	// apply delims to a subset of templates, by glob
	DelimGlobs: [glob=string]: TemplateDelims
}

#TemplateDelims: TemplateDelims
TemplateDelims: {
	LHS: string | *""
	RHS: string | *""
}